Zählfunktionen (4) ->

Text- und Zahlenblöcke zählen (335)
Aufgabe
Es sollen in einer Spalte Zahlenblöcke einer bestimmten Anzahl gezÄhlt werden.

       A               B               C       
1     3  
2     2  
3 3  1   
4 1     
5 8     
6      
7 1     
8 2     
9 7     
10 1     
11      
12 4     
13 8     
14      
15      
16 7  1   
17 5     
18 3     
19      

Lösung
Die gesuchte Anzahl zusammenhängender Zeilen mit Zahlen steht in C1.
Die Zahlen beginnen ab A2.

Mit Hilfsspalte B; - in B2 steht:
=(ANZAHL(A2:A4)=C$1)*(ANZAHL(A1:A5)=C$1)
und runterkopieren
das Ergebnis =SUMME(B:B)
(mit ANZAHL2 funktioniert das auch für Textblöcke)

ohne Hilfsspalte (nicht für Textblöcke):
{=SUMME(WENN((ZÄHLENWENN(BEREICH.VERSCHIEBEN(A2;ZEILE(1:100)-1;;C1;);">0")=C1)*(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A1;ZEILE(1:100)-1;;C1+2;);">0")=C1);1))}

Beginnen die Zahlen in A1 muss noch addiert werden:
+(ANZAHL(A1:INDIREKT("A"&C1))=C$1)*(INDIREKT("A"&C1+1)=0)

Verbesserung vom 15.07.2006: kürzer/einfacher für Text- und Zahlenblöcke und inklusive A1 von Perry:
{=SUMME(((KGRÖSSTE((A1:A100="")*ZEILE(1:100);ZEILE(1:99))-KGRÖSSTE((A1:A100="")*ZEILE(1:100);ZEILE(2:100))-1)=C1)*1)}

Zahlen- und Textblöcke insgesamt:
{=SUMME(NICHT(ISTLEER(A1:A100))*ISTLEER(A2:A101))}

zurück


gestaltet by Biene Maya